//a self-replicating drawing class
//inspired by the work of Jared Tarbell

//2008 robert carlsen // robertcarlsen.net

int initialCount = 5;
int count = initialCount;
LiveLine lines[];

boolean recording = false;
boolean doRecord = false;

void setup(){
  //faster with opengl, doesn't seem to work in a browser
  size(500,500);
  initLines(count);

}

void draw(){
    smooth();
  //loop through multiple times to speed up the drawing rate...to a point
  for(int j=0; j<constrain(initialCount,0,30);j++){
    background(204);

    //dead count. if all dead, start over
    int deathToll = 0;
    for (int i=0; i<count;i++){
      lines[i].display();
      deathToll+=int(lines[i].dead);
    }

    //print("dead: " +deathToll);
    //println(", count: " + count);
    if(deathToll >= count) {
      //println("All dead!");
      //restart
      initLines(initialCount+=2);
    }
  }

}

void initLines(int num) {
  lines = new LiveLine[num];
  count = num;
  for (int i=0; i<count;i++){
    lines[i] = new LiveLine(random(width),random(height),random(TWO_PI),2.0, random(2)+.1);
  }
}


class LiveLine {
  float x, y, a;
  float age = 1;
  int life = floor(random(500))+10;
  float weight;
  float speed = 1.0;

  boolean dead = false;

  LiveLine(float cx, float cy, float ca, float cw, float cs) {
    x = cx;
    y=cy;
    a=ca; 
    weight=cw;
    speed = cs;
  }

  void display() {
    pushMatrix();
    translate(x,y);
    rotate(a);
    strokeWeight(weight);
    float segment = (age/2.0)*speed;
    line(-segment,0,segment,0);
    if(age<life)
      age++;
    else if(!dead) {
      if(weight>.5){
        if((count+=2)>=lines.length){
          //dynamically expand the lines array as necessary
          lines = (LiveLine[]) expand(lines);
        }
        float newx = cos(a)*segment;
        float newy = sin(a)*segment;
        float newa = random(PI);
        float newspeed = speed*.90;
        lines[count-2] = new LiveLine(x+newx,y+newy,a+newa,weight*.5, newspeed);
        newa = random(PI);
        lines[count-1] = new LiveLine(x-newx,y-newy,a+newa,weight*.5,newspeed);

        //println("lines array length: " + lines.length);
        //println("current count: " + count);
      }
      //kill the current line, so i won't spawn any further
      dead = true;
    }
    popMatrix();
  }
}